singer/flake.nix

{
  description = "Rust flake";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    flake-utils.url = "github:numtide/flake-utils";
    fenix = {
      url = "github:nix-community/fenix";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs =
    {
      nixpkgs,
      flake-utils,
      fenix,
      ...
    }:
    let
      overlay =
        final: prev:
        let
          fenixPkgs = fenix.packages.${final.stdenv.hostPlatform.system};
        in
        {
          rustToolchain =
            with fenixPkgs;
            combine (
              with stable;
              [
                clippy
                rustc
                cargo
                rustfmt
                rust-src
              ]
            );
        };
    in
    {
      overlays.default = overlay;
    }
    // flake-utils.lib.eachDefaultSystem (
      system:
      let
        pkgs = import nixpkgs {
          inherit system;
          overlays = [ overlay ];
        };

        isDarwin = pkgs.stdenv.isDarwin;

        raylibWayland = pkgs.raylib.overrideAttrs (_old: {
          cmakeFlags = [
            "-DCUSTOMIZE_BUILD=ON"
            "-DBUILD_EXAMPLES=OFF"
            "-DPLATFORM=Desktop"
            "-DUSE_EXTERNAL_GLFW=ON"
            "-DINCLUDE_EVERYTHING=ON"
            "-DBUILD_SHARED_LIBS=ON"
          ];
          buildInputs = [
            pkgs.glfw
            pkgs.wayland
            pkgs.libxkbcommon
          ];
        });

        raylibDrm = pkgs.raylib.overrideAttrs (_old: {
          cmakeFlags = [
            "-DCUSTOMIZE_BUILD=ON"
            "-DBUILD_EXAMPLES=OFF"
            "-DPLATFORM=DRM"
            "-DINCLUDE_EVERYTHING=ON"
            "-DBUILD_SHARED_LIBS=ON"
          ];
          buildInputs = [
            pkgs.libdrm
            pkgs.libgbm
            pkgs.libxkbcommon
            pkgs.libinput
            pkgs.udev
            pkgs.libGL
          ];
          propagatedBuildInputs = [
            pkgs.libdrm
            pkgs.libgbm
            pkgs.libxkbcommon
            pkgs.libinput
            pkgs.udev
            pkgs.libGL
          ];
          NIX_CFLAGS_COMPILE = "-I${pkgs.libdrm.dev}/include/libdrm";
        });

        baseBuildInputs = with pkgs;
          [
            openssl
            shaderc
          ]
          ++ pkgs.lib.optionals (!isDarwin) [
            udev
          ];

        packageBuildInputs =
          baseBuildInputs
          ++ [ raylibDrm ]
          ++ pkgs.lib.optionals (!isDarwin) [
            pkgs.llvmPackages.libclang
          ];

        devShellBuildInputs =
          baseBuildInputs
          ++ [ raylibWayland ]
          ++ pkgs.lib.optionals (!isDarwin) [
            pkgs.llvmPackages.libclang
          ];

        commonNativeBuildInputs = with pkgs; [
          pkg-config
          cmake
          git
          python312
          makeWrapper
        ];

        singerPackage = pkgs.rustPlatform.buildRustPackage {
          pname = "singer";
          version = "0.1.0";

          src = pkgs.lib.cleanSource ./.;
          cargoLock.lockFile = ./Cargo.lock;

          nativeBuildInputs = commonNativeBuildInputs;
          buildInputs = packageBuildInputs;
          LIBCLANG_PATH = "${pkgs.llvmPackages.libclang.lib}/lib";

          postFixup = pkgs.lib.optionalString (!isDarwin) ''
            wrapProgram $out/bin/singer \
              --prefix LD_LIBRARY_PATH : "${pkgs.lib.makeLibraryPath packageBuildInputs}"
          '';
        };
      in
      {
        packages = {
          singer = singerPackage;
          default = singerPackage;
        };

        apps.default = {
          type = "app";
          program = "${singerPackage}/bin/singer";
        };

        devShells.default = pkgs.mkShell {
          packages =
            (with pkgs; [
              rustToolchain
              cargo-deny
              cargo-edit
              cargo-watch
              rust-analyzer
            ])
            ++ devShellBuildInputs
            ++ commonNativeBuildInputs;

          LD_LIBRARY_PATH = pkgs.lib.makeLibraryPath devShellBuildInputs;
          LIBCLANG_PATH = "${pkgs.llvmPackages.libclang.lib}/lib";

          shellHook = ''
            export RUST_SRC_PATH="${pkgs.rustToolchain}/lib/rustlib/src/rust/library"
          '';
        };
      }
    );
}