{
  description = "Rust flake";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    flake-utils.url = "github:numtide/flake-utils";
    fenix = {
      url = "github:nix-community/fenix";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs =
    {
      nixpkgs,
      flake-utils,
      fenix,
      ...
    }:
    let
      overlay =
        final: prev:
        let
          fenixPkgs = fenix.packages.${final.stdenv.hostPlatform.system};
        in
        {
          rustToolchain =
            with fenixPkgs;
            combine (
              with stable;
              [
                clippy
                rustc
                cargo
                rustfmt
                rust-src
              ]
            );
        };
    in
    {
      overlays.default = overlay;
    }
    // flake-utils.lib.eachDefaultSystem (
      system:
      let
        pkgs = import nixpkgs {
          inherit system;
          overlays = [ overlay ];
        };

        isDarwin = pkgs.stdenv.isDarwin;

        x11Libs = with pkgs; [
          wayland
          #libX11
          #libXcursor
          #libXi
          #libXrandr
          libxkbcommon
        ];

        commonBuildInputs = with pkgs;
          [
            openssl
            shaderc
          ]
          ++ pkgs.lib.optionals (!isDarwin) (
            [
              udev
              libGL
            ]
            ++ x11Libs
          );

        commonNativeBuildInputs = with pkgs; [
          pkg-config
          cmake
          git
          python312
          makeWrapper
        ];

        singerPackage = pkgs.rustPlatform.buildRustPackage {
          pname = "singer";
          version = "0.1.0";

          src = pkgs.lib.cleanSource ./.;
          cargoLock.lockFile = ./Cargo.lock;

          nativeBuildInputs = commonNativeBuildInputs;
          buildInputs = commonBuildInputs;

          postFixup = pkgs.lib.optionalString (!isDarwin) ''
            wrapProgram $out/bin/singer \
              --prefix LD_LIBRARY_PATH : "${pkgs.lib.makeLibraryPath commonBuildInputs}"
          '';
        };
      in
      {
        packages = {
          singer = singerPackage;
          default = singerPackage;
        };

        apps.default = {
          type = "app";
          program = "${singerPackage}/bin/singer";
        };

        devShells.default = pkgs.mkShell {
          packages =
            (with pkgs; [
              rustToolchain
              cargo-deny
              cargo-edit
              cargo-watch
              rust-analyzer
            ])
            ++ commonBuildInputs
            ++ commonNativeBuildInputs;

          LD_LIBRARY_PATH = pkgs.lib.makeLibraryPath commonBuildInputs;

          shellHook = ''
            export RUST_SRC_PATH="${pkgs.rustToolchain}/lib/rustlib/src/rust/library"
          '';
        };
      }
    );
}