{
  description = "MPD Discord daemon";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    flake-utils.url = "github:numtide/flake-utils";
    fenix = {
      url = "github:nix-community/fenix";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs =
    {
      self,
      nixpkgs,
      flake-utils,
      fenix,
      ...
    }:
    let
      overlay =
        final: prev:
        let
          fenixPkgs = fenix.packages.${final.stdenv.hostPlatform.system};
        in
        {
          rustToolchain =
            with fenixPkgs;
            combine (
              with stable;
              [
                clippy
                rustc
                cargo
                rustfmt
                rust-src
              ]
            );
        };
    in
    {
      overlays.default = overlay;
      homeManagerModules.mpd-discord-presence = import ./nix/mpd-discord-presence.nix;
    }
    // flake-utils.lib.eachDefaultSystem (
      system:
      let
        pkgs = import nixpkgs {
          inherit system;
          overlays = [ overlay ];
        };
      in
      {
        devShells.default = pkgs.mkShell {
          packages = with pkgs; [
            rustToolchain
            openssl
            pkg-config
            cargo-deny
            cargo-edit
            cargo-watch
            rust-analyzer
          ];

          shellHook = ''
            export RUST_SRC_PATH="${pkgs.rustToolchain}/lib/rustlib/src/rust/library"
          '';
        };

        packages = rec {
          mpd-discord-presence = pkgs.rustPlatform.buildRustPackage {
            pname = "mpd-discord-presence";
            version = "0.1.0";

            src = ./.;

            cargoLock.lockFile = ./Cargo.lock;

            enableParallelBuild = true;

            meta = {
              description = "MPD Discord daemon";
              homepage = "https://git.slendi.dev/Slendi/mpd-discord-presence";
              license = pkgs.lib.licenses.gpl3;
              mainProgrma = "mpd-discord-presence";
            };
          };
          default = mpd-discord-presence;
        };
      }
    );
}